Ada Reference Manual (Ada 2022 Draft 34)Legal Information
Contents   Index   References   Search   Previous   Next 

A.16 The Package Directories

1/2
The package Directories provides operations for manipulating files and directories, and their names. 

Static Semantics

2/2
The library package Directories has the following declaration: 
3/5
with Ada.IO_Exceptions;
with Ada.Calendar;
package Ada.Directories 
   with Global => in out synchronized is
4/2
   -- Directory and file operations:
5/2
   function Current_Directory return String;
6/2
   procedure Set_Directory (Directory : in String);
7/2
   procedure Create_Directory (New_Directory : in String;
                               Form          : in String := "");
8/2
   procedure Delete_Directory (Directory : in String);
9/2
   procedure Create_Path (New_Directory : in String;
                          Form          : in String := "");
10/2
   procedure Delete_Tree (Directory : in String);
11/2
   procedure Delete_File (Name : in String);
12/2
   procedure Rename (Old_Name, New_Name : in String);
13/2
   procedure Copy_File (Source_Name,
                        Target_Name : in String;
                        Form        : in String := "");
14/2
   -- File and directory name operations:
15/5
   function Full_Name (Name : in String) return String
      with Nonblocking;
16/5
   function Simple_Name (Name : in String) return String
      with Nonblocking;
17/5
   function Containing_Directory (Name : in String) return String
      with Nonblocking;
18/5
   function Extension (Name : in String) return String
      with Nonblocking;
19/5
   function Base_Name (Name : in String) return String
      with Nonblocking;
20/5
   function Compose (Containing_Directory : in String := "";
                     Name                 : in String;
                     Extension            : in String := "") return String
      with Nonblocking;
20.1/3
   type Name_Case_Kind is
      (Unknown, Case_Sensitive, Case_Insensitive, Case_Preserving);
20.2/3
   function Name_Case_Equivalence (Name : in String) return Name_Case_Kind;
21/2
   -- File and directory queries:
22/2
   type File_Kind is (Directory, Ordinary_File, Special_File);
23/2
   type File_Size is range 0 .. implementation-defined;
24/2
   function Exists (Name : in String) return Boolean;
25/2
   function Kind (Name : in String) return File_Kind;
26/2
   function Size (Name : in String) return File_Size;
27/2
   function Modification_Time (Name : in String) return Ada.Calendar.Time;
28/2
   -- Directory searching:
29/2
   type Directory_Entry_Type is limited private;
30/2
   type Filter_Type is array (File_Kind) of Boolean;
31/2
   type Search_Type is limited private;
32/2
   procedure Start_Search (Search    : in out Search_Type;
                           Directory : in String;
                           Pattern   : in String;
                           Filter    : in Filter_Type := (others => True));
33/2
   procedure End_Search (Search : in out Search_Type);
34/2
   function More_Entries (Search : in Search_Type) return Boolean;
35/2
   procedure Get_Next_Entry (Search : in out Search_Type;
                             Directory_Entry : out Directory_Entry_Type);
36/5
   procedure Search (
      Directory : in String;
      Pattern   : in String;
      Filter    : in Filter_Type := (others => True);
      Process   : not null access procedure (
          Directory_Entry : in Directory_Entry_Type))
      with Allows_Exit;
37/2
   -- Operations on Directory Entries:
38/2
   function Simple_Name (Directory_Entry : in Directory_Entry_Type)
       return String;
39/2
   function Full_Name (Directory_Entry : in Directory_Entry_Type)
       return String;
40/2
   function Kind (Directory_Entry : in Directory_Entry_Type)
       return File_Kind;
41/2
   function Size (Directory_Entry : in Directory_Entry_Type)
       return File_Size;
42/2
   function Modification_Time (Directory_Entry : in Directory_Entry_Type)
       return Ada.Calendar.Time;
43/2
   Status_Error : exception renames Ada.IO_Exceptions.Status_Error;
   Name_Error   : exception renames Ada.IO_Exceptions.Name_Error;
   Use_Error    : exception renames Ada.IO_Exceptions.Use_Error;
   Device_Error : exception renames Ada.IO_Exceptions.Device_Error;
44/3
private
    ... -- not specified by the language
end Ada.Directories;
45/2
External files may be classified as directories, special files, or ordinary files. A directory is an external file that is a container for files on the target system. A special file is an external file that cannot be created or read by a predefined Ada input-output package. External files that are not special files or directories are called ordinary files.
46/2
A file name is a string identifying an external file. Similarly, a directory name is a string identifying a directory. The interpretation of file names and directory names is implementation defined.
47/2
The full name of an external file is a full specification of the name of the file. If the external environment allows alternative specifications of the name (for example, abbreviations), the full name should not use such alternatives. A full name typically will include the names of all of the directories that contain the item. The simple name of an external file is the name of the item, not including any containing directory names. Unless otherwise specified, a file name or directory name parameter in a call to a predefined Ada input-output subprogram can be a full name, a simple name, or any other form of name supported by the implementation.
47.1/5
  A root directory is a directory that has no containing directory.
48/2
The default directory is the directory that is used if a directory or file name is not a full name (that is, when the name does not fully identify all of the containing directories).
49/2
A directory entry is a single item in a directory, identifying a single external file (including directories and special files).
50/2
For each function that returns a string, the lower bound of the returned value is 1.
51/2
The following file and directory operations are provided:
52/2
function Current_Directory return String;
53/2
Returns the full directory name for the current default directory. The name returned shall be suitable for a future call to Set_Directory. The exception Use_Error is propagated if a default directory is not supported by the external environment.
54/2
procedure Set_Directory (Directory : in String);
55/2
Sets the current default directory. The exception Name_Error is propagated if the string given as Directory does not identify an existing directory. The exception Use_Error is propagated if the external environment does not support making Directory (in the absence of Name_Error) a default directory.
56/2
procedure Create_Directory (New_Directory : in String;
                            Form          : in String := "");
57/2
Creates a directory with name New_Directory. The Form parameter can be used to give system-dependent characteristics of the directory; the interpretation of the Form parameter is implementation defined. A null string for Form specifies the use of the default options of the implementation of the new directory. The exception Name_Error is propagated if the string given as New_Directory does not allow the identification of a directory. The exception Use_Error is propagated if the external environment does not support the creation of a directory with the given name (in the absence of Name_Error) and form.
58/2
procedure Delete_Directory (Directory : in String);
59/3
Deletes an existing empty directory with name Directory. The exception Name_Error is propagated if the string given as Directory does not identify an existing directory. The exception Use_Error is propagated if the directory is not empty or the external environment does not support the deletion of the directory with the given name (in the absence of Name_Error).
60/2
procedure Create_Path (New_Directory : in String;
                       Form          : in String := "");
61/3
Creates zero or more directories with name New_Directory. Each nonexistent directory named by New_Directory is created. For example, on a typical Unix system, Create_Path ("/usr/me/my"); would create directory "me" in directory "usr", then create directory "my" in directory "me". The Form parameter can be used to give system-dependent characteristics of the directory; the interpretation of the Form parameter is implementation defined. A null string for Form specifies the use of the default options of the implementation of the new directory. The exception Name_Error is propagated if the string given as New_Directory does not allow the identification of any directory. The exception Use_Error is propagated if the external environment does not support the creation of any directories with the given name (in the absence of Name_Error) and form. If Use_Error is propagated, it is unspecified whether a portion of the directory path is created.
62/2
procedure Delete_Tree (Directory : in String);
63/2
Deletes an existing directory with name Directory. The directory and all of its contents (possibly including other directories) are deleted. The exception Name_Error is propagated if the string given as Directory does not identify an existing directory. The exception Use_Error is propagated if the external environment does not support the deletion of the directory or some portion of its contents with the given name (in the absence of Name_Error). If Use_Error is propagated, it is unspecified whether a portion of the contents of the directory is deleted.
64/2
procedure Delete_File (Name : in String);
65/2
Deletes an existing ordinary or special file with name Name. The exception Name_Error is propagated if the string given as Name does not identify an existing ordinary or special external file. The exception Use_Error is propagated if the external environment does not support the deletion of the file with the given name (in the absence of Name_Error).
66/2
procedure Rename (Old_Name, New_Name : in String);
67/3
Renames an existing external file (including directories) with name Old_Name to New_Name. The exception Name_Error is propagated if the string given as Old_Name does not identify an existing external file or if the string given as New_Name does not allow the identification of an external file. The exception Use_Error is propagated if the external environment does not support the renaming of the file with the given name (in the absence of Name_Error). In particular, Use_Error is propagated if a file or directory already exists with name New_Name.
68/3
procedure Copy_File (Source_Name,
                     Target_Name : in String;
                     Form        : in String := "");
69/3
Copies the contents of the existing external file with name Source_Name to an external file with name Target_Name. The resulting external file is a duplicate of the source external file. The Form parameter can be used to give system-dependent characteristics of the resulting external file; the interpretation of the Form parameter is implementation defined. Exception Name_Error is propagated if the string given as Source_Name does not identify an existing external ordinary or special file, or if the string given as Target_Name does not allow the identification of an external file. The exception Use_Error is propagated if the external environment does not support creating the file with the name given by Target_Name and form given by Form, or copying of the file with the name given by Source_Name (in the absence of Name_Error). If Use_Error is propagated, it is unspecified whether a portion of the file is copied. 
70/2
The following file and directory name operations are provided:
71/2
function Full_Name (Name : in String) return String;
72/2
Returns the full name corresponding to the file name specified by Name. The exception Name_Error is propagated if the string given as Name does not allow the identification of an external file (including directories and special files). 
73/2
function Simple_Name (Name : in String) return String;
74/5
Returns the simple name portion of the file name specified by Name. The simple name of a root directory is a name of the root itself. The exception Name_Error is propagated if the string given as Name does not allow the identification of an external file (including directories and special files).
75/2
function Containing_Directory (Name : in String) return String;
76/2
Returns the name of the containing directory of the external file (including directories) identified by Name. (If more than one directory can contain Name, the directory name returned is implementation defined.) The exception Name_Error is propagated if the string given as Name does not allow the identification of an external file. The exception Use_Error is propagated if the external file does not have a containing directory. 
77/2
function Extension (Name : in String) return String;
78/2
Returns the extension name corresponding to Name. The extension name is a portion of a simple name (not including any separator characters), typically used to identify the file class. If the external environment does not have extension names, then the null string is returned. The exception Name_Error is propagated if the string given as Name does not allow the identification of an external file. 
79/2
function Base_Name (Name : in String) return String;
80/2
Returns the base name corresponding to Name. The base name is the remainder of a simple name after removing any extension and extension separators. The exception Name_Error is propagated if the string given as Name does not allow the identification of an external file (including directories and special files). 
81/2
function Compose (Containing_Directory : in String := "";
                  Name                 : in String;
                  Extension            : in String := "") return String;
82/5
Returns the name of the external file with the specified Containing_Directory, Name, and Extension. If Extension is the null string, then Name is interpreted as a simple name; otherwise, Name is interpreted as a base name. The exception Name_Error is propagated if: 
82.1/5
the string given as Containing_Directory is not null and does not allow the identification of a directory;
82.2/5
the string given as Extension is not null and is not a possible extension;
82.3/5
the string given as Name is not a possible simple name (if Extension is null) or base name (if Extension is nonnull); or
82.4/5
the string given as Name is a root directory, and Containing_Directory or Extension is nonnull. 
82.5/3
function Name_Case_Equivalence (Name : in String) return Name_Case_Kind;
82.6/3
Returns the file name equivalence rule for the directory containing Name. Raises Name_Error if Name is not a full name. Returns Case_Sensitive if file names that differ only in the case of letters are considered different names. If file names that differ only in the case of letters are considered the same name, then Case_Preserving is returned if names have the case of the file name used when a file is created; and Case_Insensitive is returned otherwise. Returns Unknown if the file name equivalence is not known. 
83/2
The following file and directory queries and types are provided:
84/2
type File_Kind is (Directory, Ordinary_File, Special_File);
85/2
The type File_Kind represents the kind of file represented by an external file or directory.
86/2
type File_Size is range 0 .. implementation-defined;
87/2
The type File_Size represents the size of an external file. 
88/2
function Exists (Name : in String) return Boolean;
89/2
Returns True if an external file represented by Name exists, and False otherwise. The exception Name_Error is propagated if the string given as Name does not allow the identification of an external file (including directories and special files).
90/2
function Kind (Name : in String) return File_Kind;
91/2
Returns the kind of external file represented by Name. The exception Name_Error is propagated if the string given as Name does not allow the identification of an existing external file.
92/2
function Size (Name : in String) return File_Size;
93/2
Returns the size of the external file represented by Name. The size of an external file is the number of stream elements contained in the file. If the external file is not an ordinary file, the result is implementation defined. The exception Name_Error is propagated if the string given as Name does not allow the identification of an existing external file. The exception Constraint_Error is propagated if the file size is not a value of type File_Size. 
94/2
function Modification_Time (Name : in String) return Ada.Calendar.Time;
95/2
Returns the time that the external file represented by Name was most recently modified. If the external file is not an ordinary file, the result is implementation defined. The exception Name_Error is propagated if the string given as Name does not allow the identification of an existing external file. The exception Use_Error is propagated if the external environment does not support reading the modification time of the file with the name given by Name (in the absence of Name_Error). 
96/2
The following directory searching operations and types are provided:
97/2
type Directory_Entry_Type is limited private;
98/2
The type Directory_Entry_Type represents a single item in a directory. These items can only be created by the Get_Next_Entry procedure in this package. Information about the item can be obtained from the functions declared in this package. A default-initialized object of this type is invalid; objects returned from Get_Next_Entry are valid.
99/2
type Filter_Type is array (File_Kind) of Boolean;
100/2
The type Filter_Type specifies which directory entries are provided from a search operation. If the Directory component is True, directory entries representing directories are provided. If the Ordinary_File component is True, directory entries representing ordinary files are provided. If the Special_File component is True, directory entries representing special files are provided.
101/2
type Search_Type is limited private;
102/2
The type Search_Type contains the state of a directory search. A default-initialized Search_Type object has no entries available (function More_Entries returns False). Type Search_Type needs finalization (see 7.6).
103/2
procedure Start_Search (Search    : in out Search_Type;
                        Directory : in String;
                        Pattern   : in String;
                        Filter    : in Filter_Type := (others => True));
104/3
Starts a search in the directory named by Directory for entries matching Pattern and Filter. Pattern represents a pattern for matching file names. If Pattern is the null string, all items in the directory are matched; otherwise, the interpretation of Pattern is implementation defined. Only items that match Filter will be returned. After a successful call on Start_Search, the object Search may have entries available, but it may have no entries available if no files or directories match Pattern and Filter. The exception Name_Error is propagated if the string given by Directory does not identify an existing directory, or if Pattern does not allow the identification of any possible external file or directory. The exception Use_Error is propagated if the external environment does not support the searching of the directory with the given name (in the absence of Name_Error). When Start_Search propagates Name_Error or Use_Error, the object Search will have no entries available. 
105/2
procedure End_Search (Search : in out Search_Type);
106/2
Ends the search represented by Search. After a successful call on End_Search, the object Search will have no entries available.
107/2
function More_Entries (Search : in Search_Type) return Boolean;
108/2
Returns True if more entries are available to be returned by a call to Get_Next_Entry for the specified search object, and False otherwise.
109/2
procedure Get_Next_Entry (Search : in out Search_Type;
                          Directory_Entry : out Directory_Entry_Type);
110/3
Returns the next Directory_Entry for the search described by Search that matches the pattern and filter. If no further matches are available, Status_Error is raised. It is implementation defined as to whether the results returned by this subprogram are altered if the contents of the directory are altered while the Search object is valid (for example, by another program). The exception Use_Error is propagated if the external environment does not support continued searching of the directory represented by Search. 
111/5
procedure Search (
   Directory : in String;
   Pattern   : in String;
   Filter    : in Filter_Type := (others => True);
   Process   : not null access procedure (
       Directory_Entry : in Directory_Entry_Type))
   with Allows_Exit;
112/3
Searches in the directory named by Directory for entries matching Pattern and Filter. The subprogram designated by Process is called with each matching entry in turn. Pattern represents a pattern for matching file names. If Pattern is the null string, all items in the directory are matched; otherwise, the interpretation of Pattern is implementation defined. Only items that match Filter will be returned. The exception Name_Error is propagated if the string given by Directory does not identify an existing directory, or if Pattern does not allow the identification of any possible external file or directory. The exception Use_Error is propagated if the external environment does not support the searching of the directory with the given name (in the absence of Name_Error). 
113/2
function Simple_Name (Directory_Entry : in Directory_Entry_Type)
     return String;
114/2
Returns the simple external name of the external file (including directories) represented by Directory_Entry. The format of the name returned is implementation defined. The exception Status_Error is propagated if Directory_Entry is invalid.
115/2
function Full_Name (Directory_Entry : in Directory_Entry_Type)
     return String;
116/2
Returns the full external name of the external file (including directories) represented by Directory_Entry. The format of the name returned is implementation defined. The exception Status_Error is propagated if Directory_Entry is invalid.
117/2
function Kind (Directory_Entry : in Directory_Entry_Type)
     return File_Kind;
118/2
Returns the kind of external file represented by Directory_Entry. The exception Status_Error is propagated if Directory_Entry is invalid.
119/2
function Size (Directory_Entry : in Directory_Entry_Type)
     return File_Size;
120/2
Returns the size of the external file represented by Directory_Entry. The size of an external file is the number of stream elements contained in the file. If the external file represented by Directory_Entry is not an ordinary file, the result is implementation defined. The exception Status_Error is propagated if Directory_Entry is invalid. The exception Constraint_Error is propagated if the file size is not a value of type File_Size.
121/2
function Modification_Time (Directory_Entry : in Directory_Entry_Type)
     return Ada.Calendar.Time;
122/2
Returns the time that the external file represented by Directory_Entry was most recently modified. If the external file represented by Directory_Entry is not an ordinary file, the result is implementation defined. The exception Status_Error is propagated if Directory_Entry is invalid. The exception Use_Error is propagated if the external environment does not support reading the modification time of the file represented by Directory_Entry.

Implementation Requirements

123/2
 For Copy_File, if Source_Name identifies an existing external ordinary file created by a predefined Ada input-output package, and Target_Name and Form can be used in the Create operation of that input-output package with mode Out_File without raising an exception, then Copy_File shall not propagate Use_Error.

Implementation Advice

124/2
 If other information about a file (such as the owner or creation date) is available in a directory entry, the implementation should provide functions in a child package Directories.Information to retrieve it. 
125/5
 Start_Search and Search should raise Name_Error if Pattern is malformed, but not if it can represent a file in the directory but does not actually do so.
126/2
 Rename should be supported at least when both New_Name and Old_Name are simple names and New_Name does not identify an existing external file. 
127/5
NOTE 1   The operations Containing_Directory, Full_Name, Simple_Name, Base_Name, Extension, and Compose operate on file names, not external files. The files identified by these operations do not necessarily exist. Name_Error is raised only if the file name is malformed and cannot possibly identify a file. Of these operations, only the result of Full_Name depends on the current default directory; the result of the others depends only on their parameters.
128/2
NOTE 2   Using access types, values of Search_Type and Directory_Entry_Type can be saved and queried later. However, another task or application can modify or delete the file represented by a Directory_Entry_Type value or the directory represented by a Search_Type value; such a value can only give the information valid at the time it is created. Therefore, long-term storage of these values is not recommended.
129/2
NOTE 3   If the target system does not support directories inside of directories, then Kind will never return Directory and Containing_Directory will always raise Use_Error.
130/2
NOTE 4   If the target system does not support creation or deletion of directories, then Create_Directory, Create_Path, Delete_Directory, and Delete_Tree will always propagate Use_Error.
131/5
NOTE 5   To move a file or directory to a different location, use Rename. Most target systems will allow renaming of files from one directory to another. If the target file or directory can already exist, delete it first. 

Contents   Index   References   Search   Previous   Next 
Ada-Europe Ada 2005 and 2012 Editions sponsored in part by Ada-Europe