A.18.21 The Generic Package Containers.Bounded_Hashed_Maps
The language-defined generic package Containers.Bounded_Hashed_Maps
provides a private type Map and a set of operations. It provides the
same operations as the package Containers.Hashed_Maps (see
A.18.5),
with the difference that the maximum storage is bounded.
Static Semantics
The declaration of
the generic library package Containers.Bounded_Hashed_Maps has the same
contents and semantics as Containers.Hashed_Maps except:
The aspect Preelaborate is replaced with aspect
Pure. Aspect Global is deleted.
The type Map is declared
with discriminants that specify both the capacity (number of elements)
and modulus (number of distinct hash values) of the hash table as follows:
type Map (Capacity : Count_Type;
Modulus : Hash_Type) is tagged private...
Preelaborable_Initialization =>
Element_Type'Preelaborable_Initialization
and
Key_Type'Preelaborable_Initialization
The type Map needs finalization if and only if
type Key_Type or type Element_Type needs finalization.
In function Empty,
the postcondition is altered to:
Post =>
Empty'Result.Capacity = Capacity and then
Empty'Result.Modulus = Default_Modulus (Capacity) and then
not Tampering_With_Elements_Prohibited (Empty'Result) and then
not Tampering_With_Cursors_Prohibited (Empty'Result) and then
Length (Empty'Result) = 0;
The description of
Reserve_Capacity is replaced with:
procedure Reserve_Capacity (Container : in out Map;
Capacity : in Count_Type)
with Pre => Capacity <= Container.Capacity
or else raise Capacity_Error;
This operation has no effect, other than checking
the precondition.
An additional operation
is added immediately following Reserve_Capacity:
function Default_Modulus (Capacity : Count_Type)
return Hash_Type;
Default_Modulus returns an implementation-defined
value for the number of distinct hash values to be used for the given
capacity (maximum number of elements).
For procedures Insert
and Include, the part of the precondition reading:
(<some length> <= Count_Type'Last - <some other length>
or else raise Constraint_Error)
is replaced
by:
(<some length> <= Count_Type'Last - <some other length>
or else raise Constraint_Error) and then
(<some length> > Container.Capacity - <some other length>
or else raise Capacity_Error)
In procedure Assign,
the precondition is altered to:
Pre => (not Tampering_With_Cursors_Prohibited (Target)
or else raise Program_Error) and then
(Length (Source) <= Target.Capacity
or else raise Capacity_Error),
The function Copy
is replaced with:
function Copy (Source : Map;
Capacity : Count_Type := 0;
Modulus : Hash_Type := 0)
return Map
with Pre => Capacity = 0
or else Capacity >= Length (Source)
or else raise Capacity_Error,
Post =>
Length (Copy'Result) = Length (Source)
and then
not Tampering_With_Elements_Prohibited (Copy'Result)
and then
not Tampering_With_Cursors_Prohibited (Copy'Result)
and then
Copy'Result.Capacity = (
if Capacity = 0
then
Length (Source)
else Capacity)
and then
Copy'Result.Modulus = (
if Modulus = 0
then
Default_Modulus (Capacity)
else Modulus);
Returns a map with key/element pairs initialized
from the values in Source.
Bounded (Run-Time) Errors
It is a bounded error to assign
from a bounded map object while tampering with elements or cursors of
that object is prohibited. Either Program_Error is raised by the assignment,
execution proceeds with the target object prohibiting tampering with
elements or cursors, or execution proceeds normally.
Erroneous Execution
When a bounded map object
M is finalized,
if tampering with cursors is prohibited for
M other than due to
an assignment from another map, then execution is erroneous.
Implementation Requirements
For each instance of
Containers.Hashed_Maps and each instance of Containers.Bounded_Hashed_Maps,
if the two instances meet the following conditions, then the output generated
by the Map'Output or Map'Write subprograms of either instance shall be
readable by the Map'Input or Map'Read of the other instance, respectively:
the Element_Type parameters of the two instances
are statically matching subtypes of the same type; and
the output generated by Element_Type'Output or
Element_Type'Write is readable by Element_Type'Input or Element_Type'Read,
respectively (where Element_Type denotes the type of the two actual Element_Type
parameters); and
the preceding two conditions also hold for the
Key_Type parameters of the instances.
Implementation Advice
Bounded hashed map objects should be implemented
without implicit pointers or dynamic allocation.
The implementation advice for procedure Move to minimize
copying does not apply.
Ada 2005 and 2012 Editions sponsored in part by Ada-Europe
